{
  # https://github.com/anotherhadi/nixy
  description = ''
    Nixy simplifies and unifies the Hyprland ecosystem with a modular, easily customizable setup.
    It provides a structured way to manage your system configuration and dotfiles with minimal effort.
  '';

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    nixpkgs-stable.url = "github:nixos/nixpkgs/nixos-25.11";
    nixos-hardware.url = "github:NixOS/nixos-hardware/master";
    hyprland.url = "git+https://github.com/hyprwm/Hyprland?submodules=1";
    stylix.url = "github:danth/stylix";
    sops-nix.url = "github:Mic92/sops-nix";
    nvf.url = "github:notashelf/nvf";
    notashelf-tuigreet.url = "github:NotAShelf/tuigreet";
    helium-browser.url = "github:oxcl/nix-flake-helium-browser";
    nur-anotherhadi.url = "github:anotherhadi/nur-packages";
    nix-citizen.url = "github:LovingMelody/nix-citizen";
    nix-gaming.url = "github:fufexan/nix-gaming";
    nix-citizen.inputs.nix-gaming.follows = "nix-gaming";

    nix-index-database = {
      url = "github:nix-community/nix-index-database";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };


    # Server
    nixarr.url = "github:rasmus-kirk/nixarr";
    default-creds.url = "github:anotherhadi/default-creds";
    blog.url = "github:anotherhadi/blog";
    awesome-wallpapers.url = "github:anotherhadi/awesome-wallpapers";
    iknowyou.url = "github:anotherhadi/iknowyou";
  };

  outputs = inputs @ {
    nixpkgs,
    nixpkgs-stable,
    ...
  }: let
    system = "x86_64-linux";
    pkgs = nixpkgs.legacyPackages.${system};
    args = {
      inherit
        inputs
        nixpkgs
        system
        pkgs
        ;
      pkgs-stable = nixpkgs-stable.legacyPackages.${system};
      pkgs-nur-hadi = inputs.nur-anotherhadi.packages.${system};
    };
    merge = nixpkgs.lib.foldl nixpkgs.lib.recursiveUpdate {};
  in
    merge [
      (import ./home/programs/nvf/flake.nix args)
      (import ./home/programs/group/flake.nix args)
      (import ./home/programs/nixy/flake.nix args)
      {
        # Modern app output with metadata
        apps.${system} = {
          default = {
            type = "app";
            program = "${pkgs.neovim}/bin/nvim";
            meta = {
              description = "Improved Vim-based text editor";
              homepage = "https://neovim.io";
              license = "Apache-2.0";
            };
          };
        };

        # Formatter output
        formatter.${system} = pkgs.alejandra;

        # Update to modern syntax (no defaultApp)
        # Add homeManagerModules output for proper Home Manager integration
        #homeManagerModules = {
        #  dev = import ./home/programs/group/dev.nix { inherit inputs nixpkgs system; };
        #  cybersecurity = import ./home/programs/group/cybersecurity.nix { inherit inputs nixpkgs system; };
        #  basic-apps = import ./home/programs/group/basic-apps.nix { inherit inputs nixpkgs system; };
        #  misc = import ./home/programs/group/misc.nix { inherit inputs nixpkgs system; };
        #};

        nixosConfigurations = {
          thinkpad = import ./hosts/laptop/flake.nix args;
          home-pc = import ./hosts/home-pc/flake.nix args;
        };
      }
    ];
}
